A Stylized Klein Bottle

First, we define the necessary functions to describe the surface.

bx = 6 Cos[u] (1 + Sin[u]);
by = 16 Sin[u];
rad = 4 (1 - Cos[u]/2);
X = 
        If[Pi < u ≤ 2 Pi, bx + rad Cos[v + Pi], 
          bx + rad Cos[u] Cos[v]];
Y = 
        If[Pi < u ≤ 2 Pi, by, 
          by + rad Sin[u] Cos[v]];
Z = rad Sin[v];

Now, we use ParametricPlot3D to plot the surface.  In addition, we define some non-default lights for additional effect.  Subtle effects such as brown edges for the polygons are also used.

gr = 
      ParametricPlot3D[{X, Y, 
          Z, {EdgeForm[RGBColor[ .4,  .3,  .1]], 
            SurfaceColor[GrayLevel[ .25], White, 30]}}, {u, 0, 2 Pi}, {v, 0, 
          2 Pi}, PlotPoints -> 59, Axes -> False, 
        Boxed -> False, ImageSize -> 800, Background -> Black, 
        LightSources -> {{{0, 1, 1.3}, 
              RGBColor[0.3, 0.3,  .8]}, {{1, -1, 1.3}, 
              RGBColor[ .7,   .2,   .2]}, {{-1, -1, 1.3}, 
              RGBColor[0.3,   .8,  0.3]}}, 
        AmbientLight -> Black]

As an additional detail, we want to be able to see through "windows" in the surface to see hints of the internal details.  We can do this by removing some of the polygons making up the surface.  First, we extract the options so they can be reused later.

opts = gr[[2]];

Next,we extract the polygons and their style infomration which make up the first part of the graphics expression.

polys = gr[[1]];

Now, we remove every fourth polygon from the structure using the Drop command.

newpolys = Drop[polys, {1, -1, 4}];

Now, we can reassemble the graphics object to  view the result.

newgr = 
      Show[Graphics3D[newpolys], ImageSize -> {800, 600}, 
        PlotRegion -> {{- .15, 1 +  .15}, {- .15, 1 +  .15}}, 
        opts]